75 lines
3.7 KiB
Plaintext
75 lines
3.7 KiB
Plaintext
use lib_provisioning *
|
|
use utils.nu *
|
|
use handlers.nu *
|
|
use ../lib_provisioning/utils/ssh.nu *
|
|
# Provider middleware now available through lib_provisioning
|
|
|
|
# > TaskServs create
|
|
export def "main create" [
|
|
task_name?: string # task in settings
|
|
server?: string # Server hostname in settings
|
|
...args # Args for create command
|
|
--infra (-i): string # Infra directory
|
|
--settings (-s): string # Settings path
|
|
--iptype: string = "public" # Ip type to connect
|
|
--outfile (-o): string # Output file
|
|
--taskserv_pos (-p): int # Server position in settings
|
|
--check (-c) # Only check mode no taskservs will be created
|
|
--wait (-w) # Wait taskservs to be created
|
|
--select: string # Select with task as option
|
|
--debug (-x) # Use Debug mode
|
|
--xm # Debug with PROVISIONING_METADATA
|
|
--xc # Debuc for task and services locally PROVISIONING_DEBUG_CHECK
|
|
--xr # Debug for remote taskservs PROVISIONING_DEBUG_REMOTE
|
|
--xld # Log level with DEBUG PROVISIONING_LOG_LEVEL=debug
|
|
--metadata # Error with metadata (-xm)
|
|
--notitles # not tittles
|
|
--helpinfo (-h) # For more details use options "help" (no dashes)
|
|
--out: string # Print Output format: json, yaml, text (default)
|
|
]: nothing -> nothing {
|
|
if ($out | is-not-empty) {
|
|
$env.PROVISIONING_OUT = $out
|
|
$env.PROVISIONING_NO_TERMINAL = true
|
|
}
|
|
provisioning_init $helpinfo "taskserv create" ([($task_name | default "") ($server | default "")] | append $args)
|
|
if $debug { $env.PROVISIONING_DEBUG = true }
|
|
if $metadata { $env.PROVISIONING_METADATA = true }
|
|
let curr_settings = (find_get_settings --infra $infra --settings $settings)
|
|
let task = ($env.PROVISIONING_ARGS? | default "" | split row " "| get -o 0)
|
|
let options = if ($args | length) > 0 {
|
|
$args
|
|
} else {
|
|
let str_task = (($env.PROVISIONING_ARGS? | default "") | str replace $"($task) " "" |
|
|
str replace $"($task_name) " "" | str replace $"($server) " "")
|
|
($str_task | split row "-" | get -o 0 | default "" | str trim )
|
|
}
|
|
let other = if ($args | length) > 0 { ($args| skip 1) } else { "" }
|
|
let ops = $"($env.PROVISIONING_ARGS? | default "") " | str replace $"($task_name) " "" | str trim
|
|
let run_create = {
|
|
let curr_settings = (settings_with_env $curr_settings)
|
|
$env.WK_CNPROV = $curr_settings.wk_path
|
|
let arr_task = if $task_name == null or $task_name == "" or $task_name == "-" { [] } else { $task_name | split row "/" }
|
|
let match_task = if ($arr_task | length ) == 0 { "" } else { ($arr_task | get -o 0) }
|
|
let match_task_profile = if ($arr_task | length ) < 2 { "" } else { ($arr_task | get -o 1) }
|
|
let match_server = if $server == null or $server == "" { "" } else { $server}
|
|
on_taskservs $curr_settings $match_task $match_task_profile $match_server $iptype $check
|
|
}
|
|
match $task {
|
|
"" if $task_name == "h" => {
|
|
^$"($env.PROVISIONING_NAME)" -mod taskserv update help --notitles
|
|
},
|
|
"" if $task_name == "help" => {
|
|
^$"($env.PROVISIONING_NAME)" -mod taskserv update --help
|
|
_print (provisioning_options "update")
|
|
},
|
|
"c" | "create" | "" => {
|
|
let result = desktop_run_notify $"($env.PROVISIONING_NAME) taskservs create" "-> " $run_create --timeout 11sec
|
|
},
|
|
_ => {
|
|
if $task_name != "" {_print $"🛑 invalid_option ($task_name)" }
|
|
_print $"\nUse (_ansi blue_bold)($env.PROVISIONING_NAME) -h(_ansi reset) for help on commands and options"
|
|
}
|
|
}
|
|
# "" | "create"
|
|
#if not $env.PROVISIONING_DEBUG { end_run "" }
|
|
} |