use std
use ops.nu *
use ../../../providers/prov_lib/middleware.nu mw_get_ip
#  --check (-c)     # Only check mode no servers will be created
#  --wait (-w)      # Wait servers to be created
#  --select: string # Select with task as option
#  --xc             # Debuc for task and services locally PROVISIONING_DEBUG_CHECK
#  --xr             # Debug for remote servers PROVISIONING_DEBUG_REMOTE

# -  -> SSH    for server connections
export def "main ssh" [
  name?: string       # Server hostname in settings
  iptype: string = "public" # Ip type to connect
  ...args              # Args for create command
  --run               # Run ssh on 'name'
  --infra (-i): string     # Infra directory
  --settings (-s): string # Settings path
  --serverpos (-p): int   # Server position in settings
  --debug (-x)     # Use Debug mode
  --xm             # Debug with PROVISIONING_METADATA
  --xld            # Log level with DEBUG PROVISIONING_LOG_LEVEL=debug
  --metadata       # Error with metadata (-xm)
  --notitles       # not tittles
  --helpinfo (-h)  # For more details use options "help" (no dashes)
  --out: string    #  Print Output format: json, yaml, text (default)
]: nothing -> nothing {
  if ($out | is-not-empty) {
    $env.PROVISIONING_OUT = $out
    $env.PROVISIONING_NO_TERMINAL = true
  }
  provisioning_init $helpinfo "server ssh" $args
  if $debug { $env.PROVISIONING_DEBUG = true }
  if $metadata { $env.PROVISIONING_METADATA = true }
  if $name != null and $name != "h" and $name != "help" {
      let curr_settings = (find_get_settings --infra $infra --settings $settings)
      if ($curr_settings.data.servers | find $name| length) == 0 {
          _print $"🛑 invalid name ($name)"
          exit 1
      }
  }
  let task = if ($args | length) > 0 {
      ($args| get 0)
  } else {
      let str_task = ((($env.PROVISIONING_ARGS? | default "")) | str replace "ssh " " " )
      let str_task = if  $name != null {
          ($str_task | str replace $name "")
      } else {
          $str_task
      }
      ($str_task | str trim | split row " " | get -o 0 | default "" |
          split row "-" | get -o 0 | default  "" | str trim )
  }
  let other = if ($args | length) > 0 { ($args| skip 1) } else { "" }
  let ops = $"(($env.PROVISIONING_ARGS? | default "")) " | str replace $"($task) " "" | str trim
  match $task {
      "" if $name == "h" => {
          ^$"($env.PROVISIONING_NAME)" -mod server ssh help --notitles
      },
      "" if $name == "help" => {
          ^$"($env.PROVISIONING_NAME)" -mod server ssh --help
          print (provisioning_options "create")
      },
      "" | "ssh" => {
          let curr_settings = (find_get_settings --infra $infra --settings $settings)
          #let match_name = if $name == null or $name == "" { "" } else { $name}
          server_ssh $curr_settings "" $iptype $run $name
      },
      _ => {
          invalid_task "servers ssh" $task --end
      }
  }
  if not $env.PROVISIONING_DEBUG { end_run "" }
}

export def server_ssh_addr [
  settings: record
  server: record
]: nothing -> string {
  #use (prov-middleware) mw_get_ip
  let connect_ip = (mw_get_ip $settings $server $server.liveness_ip false )
  if $connect_ip == "" { return "" }
  $"($server.installer_user)@($connect_ip)"
}
export def server_ssh_id [
  server: record
]: nothing -> string {
  ($server.ssh_key_path | str replace ".pub" "")
}
export def server_ssh [
  settings: record
  request_from: string
  ip_type: string
  run: bool
  text_match?: string
]: nothing -> nothing {
  let default_port = 22
  $settings.data.servers | each { | server |
   if $text_match == null or $server.hostname == $text_match {
     on_server_ssh $settings $server $ip_type $request_from $run
   }
  }
}
def ssh_config_entry [
  server: record
  ssh_key_path: string
]: nothing -> string {
$"
Host ($server.hostname)
  User ($server.installer_user | default "root")
  HostName ($server.hostname)
  IdentityFile ($ssh_key_path)
  ServerAliveInterval 239
  StrictHostKeyChecking accept-new
  Port ($server.user_ssh_port)
"
}
export def on_server_ssh [
  settings: record
  server: record
  ip_type: string
  request_from: string
  run: bool
]: nothing -> bool {
  #use (prov-middleware) mw_get_ip
  let connect_ip = (mw_get_ip $settings $server $server.liveness_ip false )
  if $connect_ip == "" {
    _print ($"\n🛑 (_ansi red)Error(_ansi reset) no (_ansi red)($server.liveness_ip | str replace '$' '')(_ansi reset) " +
      $"found for (_ansi green)($server.hostname)(_ansi reset)"
    )
    return false
  }
  let hosts_path = "/etc/hosts"
  let ssh_key_path = ($server.ssh_key_path | str replace ".pub" "")
  if $server.fix_local_hosts {
    let ips = (^grep $server.hostname /etc/hosts | ^grep -v "^#" | ^awk '{print $1}'  | str trim | split row "\n")
    for ip in $ips {
      if ($ip | is-not-empty) and $ip != $connect_ip {
        ^sudo sed -ie $"/^($ip)/d" $hosts_path
        _print $"Delete ($ip) entry in ($hosts_path)"
      }
    }
  }
  if $server.fix_local_hosts and (^grep $connect_ip /etc/hosts | ^grep -v "^#" | ^awk '{print $1}' | is-empty) {
    if ($server.hostname | is-not-empty) { ^sudo sed -i $"/($server.hostname)/d" $hosts_path }
    let extra_hostnames = ($server.extra_hostnames | default [] | str join " ")
    ($"($connect_ip) ($server.hostname) ($extra_hostnames)\n" | ^sudo tee -a $hosts_path)
    ^ssh-keygen -f $"($env.HOME)/.ssh/known_hosts" -R $server.hostname err> (if $nu.os-info.name == "windows" { "NUL" } else { "/dev/null" })
    _print $"(_ansi green)($server.hostname)(_ansi reset) entry in ($hosts_path) added"
  }
  if $server.fix_local_hosts and (^grep $"HostName ($server.hostname)" $"($env.HOME)/.ssh/config" | ^grep -v "^#" | is-empty) {
    (ssh_config_entry $server $ssh_key_path) | save -a $"($env.HOME)/.ssh/config"
    _print $"(_ansi green)($server.hostname)(_ansi reset) entry in ($env.HOME)/.ssh/config for added"
  }
  let hosts_entry = (^grep ($connect_ip) /etc/hosts | ^grep -v "^#")
  let ssh_config_entry = (^grep $"HostName ($server.hostname)" $"($env.HOME)/.ssh/config" | ^grep -v "^#")
  if $run {
    print $"(_ansi default_dimmed)Connecting to server(_ansi reset) (_ansi green_bold)($server.hostname)(_ansi reset)\n"
    ^ssh -i (server_ssh_id $server)  (server_ssh_addr $settings $server)
    return true
  }
  match $request_from {
    "error" | "end" => {
      _print $"(_ansi default_dimmed)To connect server ($server.hostname) use:(_ansi reset)\n"
      if $ssh_config_entry != "" and $hosts_entry != "" { print $"ssh ($server.hostname) or " }
      show_clip_to $"ssh -i (server_ssh_id $server)  (server_ssh_addr $settings $server) " true
    },
    "create" => {
      _print (
        (if $ssh_config_entry != "" and $hosts_entry != "" { $"ssh ($server.hostname) or " } else { "" }) +
        $"ssh -i (server_ssh_id $server)  (server_ssh_addr $settings $server)"
      )
    }
    _ => {
      _print $"\n✅ To connect server (_ansi green_bold)($server.hostname)(_ansi reset) use:"
      if $hosts_entry == "" {
        _print $"(_ansi default_dimmed)\nAdd to /etc/hosts or DNS:(_ansi reset) ($connect_ip) ($server.hostname)"
      } else if $env.PROVISIONING_DEBUG {
        _print $"Entry for ($server.hostname) via ($connect_ip) is in ($hosts_path)"
      }
      if $ssh_config_entry == "" {
        _print $"\nVia (_ansi blue).ssh/config(_ansi reset) add entry:\n (ssh_config_entry $server $ssh_key_path)"
      } else if $env.PROVISIONING_DEBUG {
        _print $"ssh config entry for ($server.hostname) via ($connect_ip) is in ($env.HOME)/.ssh/config"
      }
      if $ssh_config_entry != "" and $hosts_entry != "" { _print $"ssh ($server.hostname) " }
      if ($env.PROVISIONING_OUT | is-empty) {
        show_clip_to $"ssh -i (server_ssh_id $server)  (server_ssh_addr $settings $server) " true
      }
    },
  }
  true
}